【UE5】Niagara SimulationStageによるシミュレーション環境構築

float3 addVelocity = float3(10, 0, 0);
OutPosition = InPosition + addVelocity;

for (int i = 0; i < InNumParticles - 1; i++)
{
    bool valid;
    float3 p;
    InParticleAttributeReader.GetVectorByIndex<Attribute="Position">(i, valid, p);

    // TODO ここでシミュレーション処理を行う
}
OutPosition = float3(1, 2, 3);

OutVelocity = float3(0.0, 0.0, 0.0);

float3 _SeparationPositionSum = float3(0.0, 0.0, 0.0);
float3 _AlignmentVelocitySum = float3(0.0, 0.0, 0.0);
float3 _CohesionPositionSum = float3(0.0, 0.0, 0.0);
int _SeparationCount = 0;
int _AlignmentCount = 0;
int _CohesionCount = 0;

bool _Valid;
float3 _Acceleration = float3(0.0, 0.0, 0.0);

// boidsの数だけチェック
for(int i = 0; i < InN; i++)
{
	// 自身は対象としない
	if(i==InID)
	{
		continue;
	}

	// 対象インデックスの位置を取得
	float3 targetPosition;
	InAttributeReader.GetVectorByIndex<Attribute="Position">(i, _Valid, targetPosition);

	// 自身との位置差分
	float3 diffPosition = InPosition - targetPosition;
	float diffLength = length(diffPosition);

	// 分離: 近づきすぎたら離れる
	if (diffLength < InSeparationDistance)
	{
		_SeparationPositionSum += diffPosition;
		_SeparationCount++;
	}

    // 整列: 近くの向きに合わせる
	if (diffLength < InAlignmentDistance)
	{
		float3 targetVelocity;
		InAttributeReader.GetVectorByIndex<Attribute="Velocity">(i, _Valid, targetVelocity);
		_AlignmentVelocitySum += targetVelocity;
		_AlignmentCount++;
	}

	// 結合: 近くのboidsの重心に近づく
	if (diffLength < InCohesionDistance)
	{
		_CohesionPositionSum += targetPosition;
		_CohesionCount++;
	}
}

// 平均を取り加速度に加算する
if(_SeparationCount > 0)
{
	float3 separationPosition = _SeparationPositionSum / _SeparationCount;
	_Acceleration += separationPosition * InSeparationCoefficient;
}
if(_AlignmentCount > 0)
{
	float3 alignmentVelocity = _AlignmentVelocitySum / _AlignmentCount;
	_Acceleration += alignmentVelocity * InAlignmentCoefficient;
}
if(_CohesionCount > 0)
{
	float3 cohesionPosition = _CohesionPositionSum / _CohesionCount;
	_Acceleration += (cohesionPosition - InPosition) * InCohesionCoefficient;
}

// 境界処理: 壁際に来たら反発力を加える
float3 avoidance = float3(0, 0, 0);
avoidance.x = (InPosition.x < -InSpaceScale) ? avoidance.x + 1.0 : avoidance.x;
avoidance.x = (InPosition.x > InSpaceScale) ? avoidance.x - 1.0 : avoidance.x;
avoidance.y = (InPosition.y < -InSpaceScale) ? avoidance.y + 1.0 : avoidance.y;
avoidance.y = (InPosition.y > InSpaceScale) ? avoidance.y - 1.0 : avoidance.y;
avoidance.z = (InPosition.z < -InSpaceScale) ? avoidance.z + 1.0 : avoidance.z;
avoidance.z = (InPosition.z > InSpaceScale) ? avoidance.z - 1.0 : avoidance.z;
_Acceleration += avoidance * InWallAvoidanceCoefficient;

// 最終的な速度
OutVelocity = InVelocity + _Acceleration;